; ------------------------------------------------------------------------
;
; Title:
;
;   PD46 -- PIC "4-pin" 19.9344 MHz to 1 Hz frequency divider
;
; Function:
;
;   This PIC program implements a digital frequency divider: the external
;   input clock is divided by a factor of 19,934,400.
;
; Diagram:
;                                ---__---
;                5V (Vdd)  +++++|1      8|=====  Ground (Vss)
;          19.9344 MHz in  ---->|2  pD  7|---->  1 Hz out
;                              -|3  46  6|-
;                              o|4      5|-
;                                --------
; Notes:
;
;   Only 4 pins are required: power (2.0-5.5V), ground, input and output.
;   o Tie input pin4/GP3 to Vdd or Vss.
;   - Other pins are all output pins.
;   Output frequency accuracy is the same as clock input accuracy.
;   Output drive current is 25 mA maximum per pin.
;   Coded for Microchip 12F675 but any '609 '615 '629 '635 '675 '683 works.
;
; Version:
;
;   25-Jan-2015  Tom Van Baak (tvb)  www.LeapSecond.com/pic
;
; ------------------------------------------------------------------------


; Microchip MPLAB IDE assembler code (mpasm).

        list        p=pic12f675
        include     p12f675.inc
        __config    _EC_OSC & _MCLRE_OFF & _WDT_OFF

; Register definitions.

        cblock  0x20            ; define register base
            gpcopy              ; shadow of output pins
        endc

; One-time PIC 12F675 initialization.

        org     0               ; power-on entry here
        bcf     STATUS,RP0      ; bank 0
        clrf    GPIO            ; set all pins low
        movlw   07h             ; set mode to turn
        movwf   CMCON           ;   comparator off
        bsf     STATUS,RP0      ; bank 1
        clrf    ANSEL-0x80      ; set digital IO (no analog A/D)
        movlw   b'101000'       ; set GP0,GP1,GP2,GP4 as output(0) and
        movwf   TRISIO-0x80     ;   other pins are input(1)
        bcf     STATUS,RP0      ; bank 0
        clrf    gpcopy          ; initialize shadow output

; With an external 19.9344 MHz clock (and 4:1 PIC execution ratio), a
; total of 2,491,800 instructions takes exactly 1/2 second per loop.
; Output pins are toggled once per loop creating a 1 Hz square wave.

Loop:   movlw   0xFF            ; (      1) -1
        xorwf   gpcopy,F        ; (      1) toggle bits
        movf    gpcopy,W        ; (      1) gpcopy -> W
        movwf   GPIO            ; (      1) W -> output pin(s)

        movlw   d'249'          ; (      1)
        call    DelayW10k       ; (2490000) delay W*10000
        movlw   d'17'           ; (      1)
        call    DelayW100       ; (   1700) delay W*100
        movlw   d'91'           ; (      1)
        call    DelayW1         ; (     91) delay (15 <= W <= 255)
        goto    Loop            ; (      2)

        include delayw.asm      ; precise delay functions
        end